La structure des instructions dans l'architecture YASEP

Les instructions de YASEP ont un format fixe sur 16 bits avec un champ optionnel, immédiat ou étendu de 16 bits. Ce format est identique pour YASEP16 et YASEP32.

Chaque instruction peut contenir :

2 bits de flags (un flag de taille 16/32 bits et un flag "immédiat")
un opcode (sur 6 bits)
jusqu'à 4 adresses de registre (chacun sur 4 bits)
une valeur immédiate sur 4 bits ou 16 bits (signée)
un code de condition (3 bits)
2 flags d'incrémentation/décrémentation automatique (2*2 bits)

Ces champs et flags ne sont pas tous utilisés en même temps. Certaines combinaisons sont impossibles par construction, d'autres n'ont aucun sens, le reste peut être transformé par l'assembleur. Cependant, une grande variété d'instructions (un opcode suivi de noms de regitres, de données immédiates et d'autres flags) peut être écrite par un programmeur. Cette page explique quelles "formes d'instructions" sont disponibles, comment elles sont structurées et quand on les utilise.

Résumé

Une "forme d'instruction" est nommée selon son écriture en langage assembleur. C'est une séquence de lettres, désignant chacune un champ :

R : registre
i : nombre immédiat court (4 bits)
I : nombre immédiat long (16 bits)

La structure du YASEP ne permet qu'un nombre limité de formes. Les deux bits de poids faible d'une instruction du YASEP déterminent comment interpréter les champs suivants, ce qui peut donner 4 combinaisons:

[00] forme courte (16 bits) à 2 registres (RR)
[10] forme courte (16 bits) à 1 registre et 1 immédiat 4 bits (iR)
[01] forme longue (32 bits) à 1 immédiat sur 16 bits et 2 registres (IRR)
[11] forme longue étendue (32 bits) avec 3 registres et d'autres fonctionnalités

La forme étendue dispose d'un flag supplémentaire qui permet d'utiliser une des adresses de registre comme immédiat sur 4 bits. Cela porte à 5 le nombre de formes physiquement possibles. L'assembleur permet d'écrire d'autres formes, par exemple en exploitant les combinaisons de champs inutilisés.

Où sont écrits les résultats ?

Le YASEP écrit le résultat des opérations (si il y a lieu) dans un registre dont l'adresse est donnée par les champs si4, snd ou dst3, en fonction de la forme de chaque instruction :

Pour les instructions "courtes" (RR, iR etc.), le résultat est écrit vers snd.
Pour les instructions "longues immédiates" (IRR or IR) le résultat est écrit vers si4.
Pour les instructions "longues étendues" (RRR, iRR etc.) le résultat est écrit vers dst3.

Les "formes courtes"

Commençons par les formes d'instructions les plus simples. Les instructions courtes ont leur bit de poids faible égal à zéro, ce qui indique une longueur de 16 bits. Il reste juste assez de place pour un autre flag, un opcode de 6 bits et 2 champs de 4 bits.

Le premier champ de 4 bits est une adresse de registre. Il s'appelle snd car il sert habituellement d'opérande source, il peut subir une négation de tous les bits (pour les soustractions et les opérations booléennes) et il sert aussi généralement d'adresse pour le registre de destination.
Le second champ de 4 bits est interprété comme une valeur immédiate signée (de -8 à 7) quand le second bit de poids faible est mis à 1, ou bien comme une adresse de registre (opérande) quand le second bit de poids faible est à 0. Ce champ s'appelle si4 car il peut servir d'opérande source ou d'immédiat sur 4 bits.

Note : avant, ces deux champs s'appelaient src1 et src2, et on les confondait tout le temps, donc il sont renommés depuis 20090730

"forme courte à registres" : deux adresses de registre

ADD R2, R1 ; R1 <= R1 + R2

15	14	13	12	11	10	9	8	7	6	5	4	3	2	1	0
si4				snd				opcode						Reg	court
R2				R1				ADD						0	0

"forme courte immédiate" : une adresse de registre et une valeur immédiate

ADD -3, R1 ; R1 <= R1 + -3

15	14	13	12	11	10	9	8	7	6	5	4	3	2	1	0
si4				snd				opcode						Imm4	court
-3				R1				ADD						1	0

En pratique, ces deux combinaisons peuvent être utilisées de 5 façons en langage assembleur, puisque chacun de ces champs peut être plus ou moins utile en fonction du type d'opération désirée :

Forme "RR" : De Registre à Registre

 ADD R1 R2   ; R2 <- R1+R2

C'est l'une des formes les plus courantes. si4 et snd donnent les adresses des deux registres contenant les opérandes. snd est aussi la destination du résultat.

Forme "iR" : immédiat court vers Registre

 ADD 2 R3   ; R3 <- 2+R3

Une autre forme courante. si4 donne une valeur immédiate, donc snd sert d'adresse de registre pour l'autre opérande source ainsi que la destination.

Forme "R" : Registre

 NEG R1   ; en interne : R1 = -R1

C'est aussi une façon courte d'écrire que les deux champs sont le même registre. L'assembleur va correctement remplir les champs si4 et snd si cette forme est acceptable pour l'opcode désiré.

Forme "i" : immédiat court

 CRIT 3   ; désactive les interruptions pour les 3 instructions suivantes

Rarement utilisé mais parfois nécessaire. si4 contient la valeur immédiate et snd est ignoré.

Forme "ALONE" : pas d'opérande

 NOP   ; pas d'opération, tout les champs sont ignorés.

C'est un cas extrême où aucune opérande n'est nécessaire. si4 et snd sont ignorés.

Les "formes longues"

YASEP interprète les instructions comme ayant une longueur de 32 bits quand leur bit de poids faible est à 1. Les 16 bits de poids faible sont exactement les mêmes que dans les formes courtes. Le second bit de poids faible indique comment interpréter le demi-mot de poids fort :

Quand il est à 0, le champ additionnel est une valeur immédiate signée de 16 bits (comprise entre -32768 et 32767) utilisée comme source pour l'opération.
Quand il est à 1, il y a un champ étendu qui fournit plus d'adresses et de fonctions. Cette partie sera complétée plus tard.

"Forme longue immédiate" : Deux adresses de registre et une valeur immédiate longue

ADD 1234, R2, R1 ; R1 <= 1234 + R2

31	30	29	28	27	26	25	24	23	22	21	20	19	18	17	16	15	14	13	12	11	10	9	8	7	6	5	4	3	2	1	0
Imm16																si4				snd				opcode						imm16	long
1234h																R2				R1				ADD						0	1

Forme "IRR" : Immédiat long et Registre vers Registre

 ADD 1234h R2 R1   ; R1 <- 1234h + R2

Cette forme est assez courante. En plus de l'opérande immédiate sur 16 bits, snd fournit l'adresse du registre qui sert de deuxième opérande. si4 donne la destination du résultat.

Forme "IR" : Immédiat long vers Registre

 GET 1234h R1   ; R1 <- SR[1234h]

Cette forme est utilisée pour les instructions GET ou MOV. Le champ si4 est ignoré parce que seul snd a un sens pour l'opération. L'assembleur détecte aussi si la valeur immédiate tient dans 4 bits pour utiliser une forme courte (FORM_iR) ou longue.

C'est aussi utilisé par les instructions booléennes (ROP2) et l'ASU (ADD et SUB) pour simuler FORM_iR mais avec une valeur immédiate sur 16 bits. Lorsqu'il trouve le flag ALIAS_IRR, l'assembleur va utiliser FORM_IRR et mettre la même adresse de registre dans les deux champs si4 et snd.

Forme "RI" : Registre vers Immédiat long

 PUT R1 1234h   ; SR[1234h] <- R1

Cette forme est uniquement utilisée pour l'instruction PUT. Elle est identique à FORM_IR mais l'ordre des opérandes est inversé par l'assembleur pour obéir à la règle n°1 selon laquelle "La destination est écrite à la fin de l'instruction".

Les formes étendues

Les formes dites "étendues" réutilisent la structure des formes courtes et rajoutent 16 bits pour fournir d'autres fonctionnalités :

Un champ d'adresse pour le registre destination (dst3 aux bits 24 à 27) qui remplace snd (qui n'est alors plus utilisé que comme source).
Un flag Imm4 auxiliaire (puisque le flag Imm4 des formes courtes indique la forme étendue)
Un champ d'adresse de registre supplémentaire pour effectuer des comparaisons (src4 aux bits 28 à 31)
Un champ de type de condition à tester (sur 3 bits, le code 0 signifie que l'instruction est toujours exécutée)
Quelques bits subsistent pour plus tard.

Ces champs sont situés dans l'instruction à des positions qui facilitent au maximum le décodage des opérandes.

"Forme Etendue à Registres" : trois adresses de registres

ADD R1, R2, R3 ; R3 <= R1 + R2

31	30	29	28	27	26	25	24	23	22	21	20	19	18	17	16	15	14	13	12	11	10	9	8	7	6	5	4	3	2	1	0
				dst3										Reg		si4				snd				opcode						Ext	long
				R3										0		R2				R1				ADD						1	1

Forme "RRR" : Registre et Registre vers Registre

 ADD R1 R2 R3 ; R3 <- R1+R2

si4 (R1) et snd (R2) sont tous les deux des registres sources, le résultat est écrit dans dst3 (R3).

"Forme Etendue Immediate" : deux adresses de registres et un champ immédiat de 4 bits

ADD 5, R1, R3 ; R3 <= R1 + 5

31	30	29	28	27	26	25	24	23	22	21	20	19	18	17	16	15	14	13	12	11	10	9	8	7	6	5	4	3	2	1	0
				dst3										Reg		si4				snd				opcode						Ext	long
				R3										1		5				R1				ADD						1	1

Form "iRR" : imm4 et Registre vers Registre

 ADD 5 R1 R3 ; R3 <- R1+5

La valeur immédiate sur 4 bits de si4 (5) et la valeur du registre indiqué par snd (R1) sont les opérandes de l'addition, dont le résultat est écrit dans dst3 (R3).